#! /bin/csh -f
#
#    script for generating an InsightII macro
#
#    the generated macro will do a sinusoidal rock of whatever is on the screen
#    and take pictures of it using take_picture.com
#
#

# rocking viewpoint
set rock_range  = 20    # degrees
set rock_period = 60    # frames
set rock_number = 1     # number of rocks (back and fourth)

set frame = 0
set maxframe = `echo $rock_period $rock_number | nawk '{printf "%d", $1*$2}'`

# wait 5 seconds to allow user to bring Insight window forward
echo 'm:Unix "sleep 5"'

while( $frame < $maxframe )
    # compute movie frame number
    set frame = `echo $frame | nawk '{printf "%04d\n", $1+1}'`

    # generate sinusoidal rotation
    set rot_step = `echo "$frame $rock_range $rock_period" | nawk '{print ($2*3.1415927/$3)*cos((6.2831853/$3)*$1)}'`
    
    set dx = $rot_step
    set dy = 0
    set dz = 0
    
    # create the desired rotation
    cat << EOF
m:Rotate * Relative ${dx},${dy},${dz} Screen
m:Unix "./take_picture.com $frame"
EOF
end